build.gradle

plugins {
    id 'java'
    id 'groovy'
    id 'idea'
    alias(libs.plugins.axionRelease)
    alias(libs.plugins.nexusPublish)
}

group = 'org.rundeck.plugins'
ext.pluginClassNames='com.plugin.sshjplugin.SSHJNodeExecutorPlugin,com.plugin.sshjplugin.SSHJFileCopierPlugin'
ext.pluginName = 'SSHJ Plugin'
ext.pluginDescription = 'SSH Node Executor and File Copier plugin based on SSHJ library.'
ext.rundeckPluginVersion= '1.2'
ext.publishName = "SSHJ Plugin ${project.version}"
ext.githubSlug = 'rundeck-plugins/sshj-plugin'
ext.developers = [
        [id: 'gschueler', name: 'Greg Schueler', email: 'greg@rundeck.com']
]

scmVersion {
    ignoreUncommittedChanges = false
    tag {
        prefix = ''           // NO "v" prefix - see PLUGIN_TAGGING_ARCHITECTURE.md
        versionSeparator = ''
    }
    versionCreator 'simple'  // Use simple version creator (just tag name)
}

allprojects {
    project.version = scmVersion.version
    apply from: "${rootDir}/gradle/java.gradle"
}

defaultTasks 'clean','build'

repositories {
    mavenLocal()
    maven {
        name = 'Central Portal Snapshots'
        url = 'https://central.sonatype.com/repository/maven-snapshots/'
        
        // Only search this repository for org.rundeck snapshots
        content {
            includeGroup('org.rundeck')
        }
    }
    mavenCentral()
}

configurations{
    //declare custom pluginLibs configuration to include only libs for this plugin
    pluginLibs

    //declare compile to extend from pluginLibs so it inherits the dependencies
    implementation{
        extendsFrom pluginLibs
    }
}

dependencies {
    pluginLibs libs.sshj
    pluginLibs libs.asnOne
    pluginLibs libs.eddsa
    pluginLibs libs.bundles.bouncycastle
    pluginLibs libs.expectitCore

    implementation libs.commonsIo
    compileOnly libs.rundeckCore
    testImplementation libs.rundeckCore
    implementation libs.slf4jApi
    
    // Add secure commons-lang3 to provide alternative to vulnerable commons-lang 2.6
    implementation(libs.commonsLang3)

    testImplementation libs.bundles.testLibs
}

configurations.all {
    resolutionStrategy {
        // Replace vulnerable commons-lang with secure commons-lang3
        dependencySubstitution {
            substitute module('commons-lang:commons-lang') using module("org.apache.commons:commons-lang3:${libs.versions.commonsLang3.get()}")
        }
    }
}

// task to copy plugin libs to output/lib dir
task copyToLib(type: Copy) {
    into "$buildDir/output/lib"
    from configurations.pluginLibs
}


jar {
    from "$buildDir/output"
    manifest {
        def libList = configurations.pluginLibs.collect{'lib/'+it.name}.join(' ')
        attributes 'Rundeck-Plugin-Name' : pluginName
        attributes 'Rundeck-Plugin-Description' : pluginDescription
        attributes 'Rundeck-Plugin-Rundeck-Compatibility-Version': '2.x+'
        attributes 'Rundeck-Plugin-Tags': 'java,executor'
        attributes 'Rundeck-Plugin-License': 'MIT'
        attributes 'Rundeck-Plugin-Source-Link': 'https://github.com/rundeck-plugins/sshj-plugin'
        attributes 'Rundeck-Plugin-Target-Host-Compatibility': 'all'
        attributes 'Rundeck-Plugin-Author': 'Rundeck, Inc.'
        attributes 'Rundeck-Plugin-Classnames': pluginClassNames
        attributes 'Rundeck-Plugin-File-Version': project.version
        attributes 'Rundeck-Plugin-Version': rundeckPluginVersion, 'Rundeck-Plugin-Archive': 'true'
        attributes 'Rundeck-Plugin-Libs': "${libList}"
    }
}

test {
    useJUnitPlatform()
    
    // Java 17+ module access for cglib/Spock mocking
    jvmArgs = [
        '--add-opens=java.base/java.lang=ALL-UNNAMED',
        '--add-opens=java.base/java.util=ALL-UNNAMED',
        '--add-opens=java.base/java.lang.reflect=ALL-UNNAMED'
    ]
}

//set jar task to depend on copyToLib
jar.dependsOn(copyToLib)

nexusPublishing {
    packageGroup = 'org.rundeck.plugins'
    repositories {
        sonatype {
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
        }
    }
}

apply from: "${rootDir}/gradle/publishing.gradle"

// Add PackageCloud repository
publishing {
    repositories {
        maven {
            name = "PackageCloudTest"
            url = uri("https://packagecloud.io/pagerduty/rundeckpro-test/maven2")
            authentication {
                header(HttpHeaderAuthentication)
            }
            credentials(HttpHeaderCredentials) {
                name = "Authorization"
                value = "Bearer " + (System.getenv("PKGCLD_WRITE_TOKEN") ?: project.findProperty("pkgcldWriteToken"))
            }
        }
    }
}