Delete file or kill buffer DWIM [Feature request]

[kaushalmodi]

I have switched to using counsel and ivy instead of ido and this is one of the features I miss from ido:

1. When doing C-x C-f, if the selection is on a file name that is not open in one of the buffers, C-k will delete (or trash, depending on delete-by-moving-to-trash) that file name.
2. When switching buffers, C-k will kill the selected buffer if open. If the buffer is already closed (virtual buffer) and if that buffer was associated to a file name, that file will be deleted (or trashed).

It will be nice to have these functionalities in counsel-find-file and ivy-switch-buffer.

Currently, I need to switch to that file/buffer and then delete/kill it.

[abo-abo]

You could add something like this to your config:

(define-key
    ivy-switch-buffer-map
    (kbd "C-k")
  (lambda ()
    (interactive)
    (ivy-set-action 'kill-buffer)
    (ivy-done)))

I'm currently working on multiple actions for a single command. Similar to counsel-describe-variable, except the key bindings aren't hard coded. Maybe that could solve your problem as well:

1. Call ivy-switch-buffer
2. C-o to open up options.
3. w / s to select the buffer kill action, instead of the default switch-to-buffer action.
4. Use C-M-n to kill a bunch of buffers, while skipping some with C-n.

[kaushalmodi]

Works great with ivy-switch-buffer. Would like to implement 'delete file' function in counsel-find-file in a similar fashion.

btw, why have the ivy- prefix for ivy-switch-buffer and counsel- for almost everything else?

[kaushalmodi]

    (defun counsel-find-file ()
      "Forward to `find-file'."
      (interactive)
      (ivy-read "Find file: " 'read-file-name-internal
                :matcher #'counsel--find-file-matcher
                :action (cons
                         1
                         `(("default"
                            (lambda (x)
                              (find-file
                               (expand-file-name x ivy--directory))))
                           (,(propertize "delete"
                                         'face 'font-lock-warning-face)
                            (lambda (x)
                              (delete-file
                               (expand-file-name x ivy--directory))))))
                :preselect (when counsel-find-file-at-point
                             (require 'ffap)
                             (ffap-guesser))
                :require-match 'confirm-after-completion
                :history 'file-name-history
                :keymap counsel-find-file-map))

[abo-abo]

btw, why have the ivy- prefix for ivy-switch-buffer and counsel- for almost everything else?

Because most of ivy-switch-buffer is in ivy.el, and it's part of ivy-mode via:

(define-key map [remap switch-to-buffer] 'ivy-switch-buffer)

I tried remapping counsel-find-file, it didn't work for some reason.

[abo-abo]

Would like to implement 'delete file' function in counsel-find-file in a similar fashion.

I'm afraid of deleting files by accident: by mashing sc you can delete a file by accident. But I don't want to make you redefine counsel-find-file if you choose to have that functionality. Maybe I could add ivy-extra-actions-alist similar to ivy-initial-inputs-alist. What do you think?

[kaushalmodi]

Maybe I could add ivy-extra-actions-alist similar to ivy-initial-inputs-alist.

I am fine redefining that function. But adding that variable would also mean easy customizability of any function using ivy; so go for it. Thanks! :)

I also feared of accidental deletion and so I gave font-lock-warning-face to delete option. I can even go further and wrap the delete-file in y-or-n-p.

[abo-abo]

Added the new interface. Give it a try for your file-deleting application.

[kaushalmodi]

Works great! Thank you.

(ivy-set-actions
 'counsel-find-file
 `((,(propertize "delete" 'face 'font-lock-warning-face)
    (lambda (x) (delete-file (expand-file-name x ivy--directory))))))