epanet-msx-python/CMakeLists.txt at main · OpenWaterAnalytics/epanet-msx-python · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
cmake_minimum_required(VERSION 3.12)

project(epanet-msx)
set(Python3_EXECUTABLE ${PYTHON_EXECUTABLE})

if(SKBUILD)
  message(STATUS "The project is built using scikit-build")
endif()

# Setup python
if(NOT MSVC)
    find_package (Python3 ${PYTHON_VERSION_STRING} COMPONENTS Interpreter Development.Module EXACT REQUIRED)
else()
    find_package (Python3 ${PYTHON_VERSION_STRING} COMPONENTS Interpreter Development EXACT REQUIRED)
endif()


# Setup swig
find_package(SWIG REQUIRED)
cmake_policy(SET CMP0078 NEW)
cmake_policy(SET CMP0086 NEW)
include(${SWIG_USE_FILE})
set(CMAKE_SWIG_FLAGS -py3)

# Build the msx library
ADD_SUBDIRECTORY(epanet-msx/MSX\ Core)

# Set up rpath on MacOS and Linux
if(APPLE)
    set(PACKAGE_RPATH "@loader_path")
else()
    set(PACKAGE_RPATH "$ORIGIN")
endif()


# Include files for swig
INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR})
INCLUDE_DIRECTORIES(epanet-msx/MSX\ Core/include)

# Allow target_include_directories to be used later
set_property(SOURCE wrapper/toolkit.i
    PROPERTY
        USE_TARGET_INCLUDE_DIRECTORIES TRUE
)
set_property(TARGET msxcore
    PROPERTY
        USE_TARGET_INCLUDE_DIRECTORIES TRUE
)

# Create cmake target
swig_add_library(toolkit
    TYPE
        MODULE
    LANGUAGE
        python
    SOURCES
        wrapper/toolkit.i
)

target_include_directories(toolkit
    PUBLIC
        ${Python3_INCLUDE_DIRS}
)


target_link_options(toolkit
    PUBLIC
        $<$<BOOL:${APPLE}>:-undefined dynamic_lookup>
)


swig_link_libraries(toolkit
    PUBLIC
        $<$<BOOL:$<C_COMPILER_ID:MSVC>>:Python3::Module>
        msxcore
)

set_target_properties(toolkit
    PROPERTIES
        SWIG_COMPILE_DEFINITIONS EXPORT_OUT_API
        MACOSX_RPATH TRUE
        SKIP_BUILD_RPATH FALSE
        BUILD_WITH_INSTALL_RPATH FALSE
        INSTALL_RPATH "${PACKAGE_RPATH}"
        INSTALL_RPATH_USE_LINK_PATH TRUE
)

install(TARGETS toolkit LIBRARY DESTINATION packages/epanetmsx)

add_custom_command(
    TARGET toolkit
    POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy
        "${CMAKE_CURRENT_BINARY_DIR}/toolkit.py"
        $<$<BOOL:${WIN32}>:${CMAKE_CURRENT_BINARY_DIR}/_toolkit.pyd>
        $<$<BOOL:${WIN32}>:${CMAKE_CURRENT_BINARY_DIR}/bin/msxcore.dll>
        $<$<NOT:$<BOOL:${WIN32}>>:${CMAKE_CURRENT_BINARY_DIR}/lib/libmsxcore.*>
        ${CMAKE_SOURCE_DIR}/packages/epanetmsx
)