Introduce wrapper to avoid access types in instrument-c.adb

Using 'Access or 'Address should be avoided when used to implement OUT
parameters. Create subprograms that wrap thin C bindings to avoid this,
and refactor instrument-c.adb accordingly.

Change-Id: I40ca1268e18e7099bce6604ff94128a559582fec
TN: V916-015

Author: pmderodat

tools/gnatcov/clang-extensions.adb

@@ -22,8 +22,23 @@
 
 with Clang.CX_String; use Clang.CX_String;
 
+with Files_Table; use Files_Table;
+
 package body Clang.Extensions is
 
+   function To_Sloc (Line, Column : unsigned) return Local_Source_Location is
+     ((Natural (Line), Natural (Column)));
+   --  Convert a Clang local source location to gnatcov's own format
+
+   function To_Sloc
+     (File : File_T; Line, Column : unsigned) return Source_Location
+   is
+     ((Source_File => Get_Index_From_Generic_Name
+                        (Name => Get_File_Name (File),
+                         Kind => Source_File),
+       L           =>  To_Sloc (Line, Column)));
+   --  Convert a Clang source location to gnatcov's own format
+
    --------------------
    -- Get_Opcode_Str --
    --------------------
@@ -82,6 +97,50 @@ package body Clang.Extensions is
       CX_Rewriter_Insert_Text_After_Token_C (Rew, Loc, Insert & ASCII.NUL);
    end CX_Rewriter_Insert_Text_After_Token;
 
+   -----------------------
+   -- Spelling_Location --
+   -----------------------
+
+   function Spelling_Location (Loc : Source_Location_T) return Source_Location
+   is
+      File                 : File_T;
+      Line, Column, Offset : aliased unsigned;
+   begin
+      Get_Spelling_Location
+        (Loc, File'Address, Line'Access, Column'Access, Offset'Access);
+
+      return To_Sloc (File, Line, Column);
+   end Spelling_Location;
+
+   -------------------
+   -- File_Location --
+   -------------------
+
+   function File_Location
+     (Loc : Source_Location_T) return Local_Source_Location
+   is
+      File                 : File_T;
+      Line, Column, Offset : aliased unsigned;
+   begin
+      Get_File_Location
+        (Loc, File'Address, Line'Access, Column'Access, Offset'Access);
+      return To_Sloc (Line, Column);
+   end File_Location;
+
+   -----------------------
+   -- Presumed_Location --
+   -----------------------
+
+   function Presumed_Location
+     (Loc : Source_Location_T) return Local_Source_Location
+   is
+      Filename     : aliased String_T;
+      Line, Column : aliased unsigned;
+   begin
+      Get_Presumed_Location (Loc, Filename'Access, Line'Access, Column'Access);
+      return To_Sloc (Line, Column);
+   end Presumed_Location;
+
    -----------------------
    -- Is_Macro_Location --
    -----------------------
@@ -102,7 +161,7 @@ package body Clang.Extensions is
 
    function Is_Macro_Arg_Expansion
      (Loc       : Source_Location_T;
-      Start_Loc : access Source_Location_T := null;
+      Start_Loc : out Source_Location_T;
       TU        : Translation_Unit_T) return Boolean
    is
       function Is_Macro_Arg_Expansion
@@ -112,8 +171,14 @@ package body Clang.Extensions is
         with
           Import, Convention => C,
           External_Name      => "clang_isMacroArgExpansion";
+
+      C_Start_Loc : aliased Source_Location_T;
    begin
-      return Is_Macro_Arg_Expansion (Loc, Start_Loc, TU) /= 0;
+      return Result : constant Boolean :=
+        Is_Macro_Arg_Expansion (Loc, C_Start_Loc'Access, TU) /= 0
+      do
+         Start_Loc := C_Start_Loc;
+      end return;
    end Is_Macro_Arg_Expansion;
 
    ----------------------------------------------

tools/gnatcov/clang-extensions.ads

@@ -25,6 +25,8 @@ with Interfaces.C; use Interfaces.C;
 with Clang.Index;   use Clang.Index;
 with Clang.Rewrite; use Clang.Rewrite;
 
+with Slocs; use Slocs;
+
 package Clang.Extensions is
 
    function Get_Body (C : Cursor_T) return Cursor_T
@@ -114,13 +116,26 @@ package Clang.Extensions is
    --  The functions below are simply bindings around clang functions, which
    --  are exhaustively documented in the clang sources.
 
+   function Spelling_Location (Loc : Source_Location_T) return Source_Location
+     with Inline;
+   --  Thick binding for Clang.Index.Get_Spelling_Location
+
+   function File_Location
+     (Loc : Source_Location_T) return Local_Source_Location
+     with Inline;
+   --  Thick binding for Clang.Index.Get_File_Location
+
+   function Presumed_Location
+     (Loc : Source_Location_T) return Local_Source_Location;
+   --  Thick binding for Clang.Index.Get Presumed_Location
+
    function Is_Macro_Location (Loc : Source_Location_T) return Boolean
      with Inline;
    --  See isMacroID in clang/Basic/SourceLocation.h.
 
    function Is_Macro_Arg_Expansion
      (Loc       : Source_Location_T;
-      Start_Loc : access Source_Location_T := null;
+      Start_Loc : out Source_Location_T;
       TU        : Translation_Unit_T) return Boolean
       with Inline;
    --  See isMacroArgExpansion in clang/Basic/SourceManager.h.

tools/gnatcov/instrument-c.adb

@@ -565,12 +565,8 @@ package body Instrument.C is
       Last               : Boolean;
       Pragma_Aspect_Name : Name_Id := Namet.No_Name)
    is
-      Loc : Source_Location_T :=
-        Get_Range_Start (Get_Cursor_Extent (N));
-
-      Line, Column, Offset : aliased unsigned;
-      File                 : File_T;
-      Info                 : PP_Info;
+      Loc  : Source_Location_T := Get_Range_Start (Get_Cursor_Extent (N));
+      Info : PP_Info;
    begin
       Append_SCO (C1, C2, From, To, Last, Pragma_Aspect_Name);
 
@@ -591,14 +587,10 @@ package body Instrument.C is
             Expansion_Stack : Expansion_Lists.List;
             Definition_Info : Expansion_Info;
 
-            Macro_Expansion_Name      : US.Unbounded_String;
-            Immediate_Expansion_Loc_C : Source_Location_T;
-            Immediate_Expansion_Loc   : Source_Location;
-
-            Macro_Arg_Expanded_Loc_C : aliased Source_Location_T;
-            Macro_Arg_Expanded_Loc   : Source_Location;
+            Macro_Expansion_Name    : US.Unbounded_String;
+            Immediate_Expansion_Loc : Source_Location_T;
+            Macro_Arg_Expanded_Loc  : Source_Location_T;
          begin
-
             --  Note: macro arguments are completely macro-expanded before they
             --  are substituted in a macro body, unless they are stringified or
             --  pasted with other tokens.
@@ -662,53 +654,26 @@ package body Instrument.C is
             --  So we have to get the macro argument expansion location, and
             --  get its spelling location.
 
-            if Is_Macro_Arg_Expansion
-              (Loc, Macro_Arg_Expanded_Loc_C'Access, UIC.TU)
+            if Is_Macro_Arg_Expansion (Loc, Macro_Arg_Expanded_Loc, UIC.TU)
             then
-               Get_Spelling_Location
-                 (Macro_Arg_Expanded_Loc_C,
-                  File'Address,
-                  Line'Access,
-                  Column'Access,
-                  Offset'Access);
-               Macro_Arg_Expanded_Loc :=
-                 (Source_File =>
-                    Get_Index_From_Generic_Name
-                      (Name => Get_File_Name (File),
-                       Kind => Source_File),
-                  L           =>  (Natural (Line), Natural (Column)));
-
                Macro_Expansion_Name :=
                  +Get_Immediate_Macro_Name_For_Diagnostics
-                    (Macro_Arg_Expanded_Loc_C, UIC.TU);
+                    (Macro_Arg_Expanded_Loc, UIC.TU);
 
                Definition_Info :=
                  (Macro_Name => Macro_Expansion_Name,
-                  Sloc       => Macro_Arg_Expanded_Loc);
+                  Sloc       => Spelling_Location (Macro_Arg_Expanded_Loc));
             else
-               Get_Spelling_Location
-                 (Loc,
-                  File'Address,
-                  Line'Access,
-                  Column'Access,
-                  Offset'Access);
-
-               Immediate_Expansion_Loc :=
-                 (Source_File =>
-                    Get_Index_From_Generic_Name
-                      (Name => Get_File_Name (File),
-                       Kind => Source_File),
-                  L           => (Natural (Line), Natural (Column)));
                Macro_Expansion_Name :=
                  +Get_Immediate_Macro_Name_For_Diagnostics (Loc, UIC.TU);
                Definition_Info :=
                  (Macro_Name => Macro_Expansion_Name,
-                  Sloc       => Immediate_Expansion_Loc);
+                  Sloc       => Spelling_Location (Loc));
             end if;
 
             while Is_Macro_Location (Loc) loop
 
-               Immediate_Expansion_Loc_C := Loc;
+               Immediate_Expansion_Loc := Loc;
 
                --  Find the location of the immediately expanded macro. Getting
                --  the immediate expansion location yields a location in the
@@ -747,9 +712,7 @@ package body Instrument.C is
                --  as implemented in clang.
 
                while Is_Macro_Arg_Expansion
-                 (Immediate_Expansion_Loc_C,
-                  Macro_Arg_Expanded_Loc_C'Access,
-                  UIC.TU)
+                 (Immediate_Expansion_Loc, Macro_Arg_Expanded_Loc, UIC.TU)
                loop
                   --  TODO??? Document why it is needed to loop while we are
                   --  in a macro argument expansion (did not manage to make an
@@ -758,31 +721,17 @@ package body Instrument.C is
                   --  Get_Immediate_Macro_Name_For_Diagnostics implemented in
                   --  clang.
 
-                  Immediate_Expansion_Loc_C :=
+                  Immediate_Expansion_Loc :=
                     Get_Immediate_Expansion_Loc
-                      (Immediate_Expansion_Loc_C, UIC.TU);
+                      (Immediate_Expansion_Loc, UIC.TU);
                end loop;
 
-               --  Immediate_Expansion_Loc is the location of the token in
-               --  the immediate expanded macro definition. To get to the
-               --  expansion point, go up one level.
-
-               Immediate_Expansion_Loc_C :=
-                 Get_Immediate_Expansion_Loc
-                   (Immediate_Expansion_Loc_C, UIC.TU);
-               Get_Spelling_Location
-                 (Immediate_Expansion_Loc_C,
-                  File'Address,
-                  Line'Access,
-                  Column'Access,
-                  Offset'Access);
+               --  Immediate_Expansion_Loc is the location of the token in the
+               --  immediate expanded macro definition. To get to the expansion
+               --  point, go up one level.
 
                Immediate_Expansion_Loc :=
-                 (Source_File =>
-                    Get_Index_From_Generic_Name
-                      (Name => Get_File_Name (File),
-                       Kind => Source_File),
-                  L           => (Natural (Line), Natural (Column)));
+                 Get_Immediate_Expansion_Loc (Immediate_Expansion_Loc, UIC.TU);
                Macro_Expansion_Name :=
                  +Get_Immediate_Macro_Name_For_Diagnostics (Loc, UIC.TU);
 
@@ -797,7 +746,8 @@ package body Instrument.C is
                if Length (Macro_Expansion_Name) /= 0 then
                   Expansion_Stack.Append
                     ((Macro_Name => Macro_Expansion_Name,
-                      Sloc       => Immediate_Expansion_Loc));
+                      Sloc       => Spelling_Location
+                                      (Immediate_Expansion_Loc)));
                end if;
             end loop;
 
@@ -844,9 +794,6 @@ package body Instrument.C is
             End_Loc               : constant Source_Location_T :=
               Get_Range_End (Cursor_Source_Range_C);
 
-            Line, Column, Offset : aliased unsigned;
-            File                 : File_T;
-
             Cursor_Source_Range : Slocs.Local_Source_Location_Range;
 
             procedure Update (LL_SCO : Nat; Info : in out PP_Info);
@@ -864,28 +811,13 @@ package body Instrument.C is
             end Update;
 
          begin
-            --  Get start of the range
-
-            Get_File_Location
-              (Start_Loc,
-               File'Address,
-               Line'Access,
-               Column'Access,
-               Offset'Access);
-            Cursor_Source_Range.First_Sloc :=
-              (Line => Natural (Line), Column => Natural (Column));
-
-            --  Get end of the range. Note: end column is exclusive
-
-            Get_File_Location
-              (End_Loc,
-               File'Address,
-               Line'Access,
-               Column'Access,
-               Offset'Access);
-
-            Cursor_Source_Range.Last_Sloc :=
-              (Line => Natural (Line), Column => Natural (Column) - 1);
+            --  Get start and end of the range. Note: End_Loc is exclusive,
+            --  whereas we need Cursor_Source_Range.Last_Sloc to be inclusive.
+
+            Cursor_Source_Range.First_Sloc := File_Location (Start_Loc);
+            Cursor_Source_Range.Last_Sloc := File_Location (End_Loc);
+            Cursor_Source_Range.Last_Sloc.Column :=
+              Cursor_Source_Range.Last_Sloc.Column - 1;
 
             UIC.LL_PP_Info_Map.Update_Element
               (UIC.LL_PP_Info_Map.Find (SCOs.SCO_Table.Last), Update'Access);

tools/gnatcov/instrument-c_utils.adb

@@ -34,49 +34,30 @@ package body Instrument.C_Utils is
    ----------
 
    function Sloc (Loc : Source_Location_T) return Local_Source_Location is
-      Line, Column : aliased Interfaces.C.unsigned;
    begin
-      Get_Presumed_Location (Location => Loc,
-                             Filename => null,
-                             Line     => Line'Access,
-                             Column   => Column'Access);
-      return (Natural (Line), Natural (Column));
+      return Presumed_Location (Loc);
    end Sloc;
 
    ----------------
    -- Start_Sloc --
    ----------------
 
    function Start_Sloc (N : Cursor_T) return Local_Source_Location is
-      Line, Column : aliased Interfaces.C.unsigned;
-      Loc          : constant Source_Location_T :=
-        Get_Range_Start (Get_Cursor_Extent (N));
    begin
-      Get_Presumed_Location (Location => Loc,
-                             Filename => null,
-                             Line     => Line'Access,
-                             Column   => Column'Access);
-      return (Natural (Line), Natural (Column));
+      return Presumed_Location (Get_Range_Start (Get_Cursor_Extent (N)));
    end Start_Sloc;
 
    --------------
    -- End_Sloc --
    --------------
 
    function End_Sloc (N : Cursor_T) return Local_Source_Location is
-      Line, Column : aliased Interfaces.C.unsigned;
-      Loc          : Source_Location_T :=
-        Get_Range_End (Get_Cursor_Extent (N));
+      Loc : Source_Location_T := Get_Range_End (Get_Cursor_Extent (N));
    begin
       if Is_Macro_Location (Loc) then
          Loc := Get_Expansion_End (Get_Cursor_TU (N), Loc);
       end if;
-      Get_Presumed_Location
-        (Location => Loc,
-         Filename => null,
-         Line     => Line'Access,
-         Column   => Column'Access);
-      return (Natural (Line), Natural (Column));
+      return Presumed_Location (Loc);
    end End_Sloc;
 
    ----------